●Ａ／Ｄ変換 を使ってみよう
ＰＩＣではアナログ信号（電圧）をデジタルデータに変換するＡ／Ｄ変換機能が搭載されて
おり、とても興味がありますので簡単な動作確認レベルで使ってみることにしました。
・アナログ信号源（電圧データ）
可変抵抗の半固定ボリューム（１０ＫΩ）を利用して、０Ｖ～約５Ｖ（電源電圧）までの
範囲で、アナログ信号としての電圧データを発生させます。
・Ａ／Ｄ変換後の値を測定する
アナログ信号を入力してＡ／Ｄ変換実行後のデジタルデータ（測定値）を、ＥＥＰＲＯＭ
に保存（記憶）させて、測定値の推移を調べます。
・
・
・
・
・
●配線図です。
■プログラムは・・・
サーボコントローラ 改良版１（ＳＡＴＢＶＢ０１ ）を流用して、Ａ／Ｄ変換処理部分を
追加する方法で作りました。
------------------------------------------------------------------------------
・ＳＡＴＢＶＤ０１（ ＶＥＲ ０Ｄ.０１ ） サーボコントローラ 改良版３
追加機能：Ａ／Ｄ変換
Ａ／Ｄ変換値をＥＥＰＲＯＭに保存（記憶）する。
------------------------------------------------------------------------------
【 PIC12F683 】
__________ __________
| V |
| |
3～5V+ --+ 1 Vdd(+) | Vss(-) 8 +-- 0V
--+ 2 GP5 |OUT GP0 7 +--> ｻｰﾎﾞ
--+ 3 GP4 | GP1 6 +--< アナログ信号（電圧）
ｻｰﾎﾞ-->+ 4 GP3 IN | GP2 5 +--< SW.NEUTRAL
| |
+---------------------+
●Ａ／Ｄ変換機能について
■使用環境
・基準電圧 ： 約５V ( 電源電圧を使用する )
・測定電圧 ： ０～約５V（ 基準電圧内で ）
・A/D変換値 ： 10ビット （ 00 0000 0000 ～ 11 1111 1111 ）
・変換段階数： 1023
■A/D変換出力値
測定電圧（Ｖ）÷ 基準電圧(電源電圧)（Ｖ）Ｘ 1023(変換段階数) ＝ A/D変換出力値
■A/D変換出力値は、10ビットなので下記値の範囲内で表現される。
・10ビットの表現（2進数） ： 00 0000 0000 ～ 11 1111 1111
・10ビットの表現（10進数）： 0 ～ 1023
・10ビットの表現（16進数）： 0 00 ～ 3 FF
＊高精度値を求めないなら、上位８ビットを使用した方が扱いやすい感じがする。
（ 0 ～ 1020 ）
■最小測定電圧（分解能）
基準電圧(電源電圧)（Ｖ）÷ 1023(変換段階数) ＝ 最小測定電圧（分解能）（ｍＶ）
５Ｖ ÷ １０２３段階数 = 約４.９ ｍＶ
最小約４.９ ｍＶの分解能となるので、この単位が最小測定電圧となる。
●既存の初期設定に対して、Ａ／Ｄ変換機能の設定を反映した部分です。
;---Ａ／Ｄ変換の(ｸﾛｯｸ･入力ﾋﾟﾝ)設定--- ｱﾅﾛｸﾞ入力ﾋﾟﾝ(GP1のみ),他入力ﾋﾟﾝはデジタルにする
MOVLW B'00010010' ;Ｗレジスタ ← ＧＰ１のみアナログ入力ピンとして使う
;未使用 ：ﾋﾞｯﾄ：7(0)
;Ａ／Ｄ変換クロック選択(8Tosc)：ﾋﾞｯﾄ：6-4(001)
;アナログ／デジタル選択(GP1) ：ﾋﾞｯﾄ：3-0(0010)
MOVWF ANSEL ;ＡＮＳＥＬレジスタ ← Ｗレジスタ
;---入力ピン--- アナログ入力ピン（ＧＰ１のみ）、他入力ピンはデジタルＩ／Ｏ
MOVLW B'00001110' ;Ｗレジスタ ← ＧＰ１、２、３を入力ピンとして使う
MOVWF TRISIO ;ＴＲＩＳＩＯレジスタ ← Ｗレジスタ
;---Ａ／Ｄ変換動作の設定---
MOVLW B'10000101' ;Ｗﾚｼﾞｽﾀ ← A/D変換結果:左詰め,基準電圧:電源電圧 で使う
;A/D変換結果(右詰め):ﾋﾞｯﾄ7(1)
;基準電圧(電源電圧):ﾋﾞｯﾄ6(0)
;未使用 :ﾋﾞｯﾄ5-4(00)
;Ａ／Ｄ変換のチャネル（AN1）:ﾋﾞｯﾄ3-2(01)
;A/D変換状態(完了):ﾋﾞｯﾄ1(0)
;A/D変換状態(有効):ﾋﾞｯﾄ0(1)
MOVWF ADCON0 ;ＡＤＣＯＮ０レジスタ ← Ｗレジスタ
・
・
・
・
・
●サンプリングコンデンサへの充電時間（アクイジション時間）について
Ａ／Ｄ変換の実行を開始するのに、前処理としてＡ／Ｄ変換準備の完了を待ちます。目的は
アナログ信号（電圧）の情報源となるＰＩＣ内蔵コンデンサの充電が完了する必要があり、
この充電が完了する時間をアクィジション時間と言われています。
Ａ／Ｄ変換のクロック指定は、ＰＩＣを動作させるオシレータ（クロック）の周波数と、Ａ
ＮＳＥＬレジスタのＡＤＣＳ２～０など、下記の設定で決めています。
・オシレータ ：４ＭＨｚ
・Ａ／Ｄ変換のクロック指定：８Ｔｏｓｃ( オシレータの１クロック<１サイクル> Ｘ ８ )
アクイジション時間は、２．０μ秒となり、入力の抵抗抵抗が１０ＫΩですので、プログラ
ム内で、時間調整処理を約２０μ秒しており、この方法でＡ／Ｄ変換準備の完了判断してい
ます。
■しかしながら・・・ちょっと、変な対応？ しちゃいましたです。(^^；
既存のサーボコントローラプログラムの中にＡ／Ｄ変換処理ステップを追加していますので
プログラムロジック的に推奨されるアクイジション時間以上は確保できていますので、考慮
する必要はないのですが、Ａ／Ｄ変換の実行条件を安定させたいので、適用するＡ／Ｄ変換
実行の直前にリセットもどきのダミー処理（Ａ／Ｄ変換）を２回してから、アクイジション
時間の時間調整処理を約２０μ秒しています。こんな方法で良いのかしら？
●Ａ／Ｄ変換の実行処理したサブルーチン部分です。
;******************************************************************************************
;* Ａ／Ｄ変換処理 *
;******************************************************************************************
;
; ①Ａ／Ｄ変換（１回目）：ダミー処理としてＡ／Ｄ変換を完了する
; ②Ａ／Ｄ変換（２回目）：ダミー処理としてＡ／Ｄ変換を完了する
; ③Ａ／Ｄ変換（３回目）：この処理のＡ／Ｄ変換を適用し、Ａ／Ｄ変換結果(10ﾋﾞｯﾄ) を取得する
; ・ADHSAV(Ａ／Ｄ変換値上位)：ADRESHレジスタ(A/D変換結果上位) をセットする
; ・ADLSAV(Ａ／Ｄ変換値下位)：ADRESLレジスタ(A/D変換結果下位) をセットする
;----
ADHEN_RTN
;---- ①Ａ／Ｄ変換（１回目）これは、ダミー処理です
;---Ａ／Ｄ変換を開始する （ＧＯビットをＯＮ＜１＞にする）
BSF ADCON0,GO ;ADCON0レジスタ（ＧＯビット） ← 1
;---Ａ／Ｄ変換の完了を待つ（ＧＯビットがＯＦＦ＜０＞になるまで）
ADHEN_LOOP1
BTFSC ADCON0,GO ;ADCON0レジスタ（GOﾋﾞｯﾄ）＝０の時 次の命令をスキップする
GOTO ADHEN_LOOP1 ;ADHEN_LOOP1へ ジャンプする （Ａ／Ｄ変換完了待ちループ）
;---- ②Ａ／Ｄ変換（２回目）これは、ダミー処理です
;---Ａ／Ｄ変換を開始する （ＧＯビットをＯＮ＜１＞にする）
BSF ADCON0,GO ;ADCON0レジスタ（ＧＯビット） ← 1
;---Ａ／Ｄ変換の完了を待つ（ＧＯビットがＯＦＦ＜０＞になるまで）
ADHEN_LOOP2
BTFSC ADCON0,GO ;ADCON0レジスタ（GOﾋﾞｯﾄ）＝０の時 次の命令をスキップする
GOTO ADHEN_LOOP2 ;ADHEN_LOOP2へ ジャンプする （Ａ／Ｄ変換完了待ちループ）
;---- ③Ａ／Ｄ変換（３回目）この処理を適用する
MOVLW 0 ;Ｗレジスタ ← ０（ゼロ）
MOVWF ADHSAV ;ADHSAV （Ａ／Ｄ変換値上位） ← Ｗレジスタ
MOVWF ADLSAV ;ADLSAV （Ａ／Ｄ変換値下位） ← Ｗレジスタ
;---Ａ／Ｄ変換時間待ち（約20u秒）の判断 ＜ADHCNT＝０：約20u秒オーバーになった状態＞
;---ＰＩＣ内蔵コンデンサの充電を待つ時間(20u秒)、入力抵抗が１０ＫΩの時、約２０μ秒要
MOVLW D'5' ;Ｗレジスタ ← ５
MOVWF ADHCNT ;ADHCNT(Ａ／Ｄ変換待ち時間カウント) ← Ｗレジスタ
ADHEN_LOOP3
DECFSZ ADHCNT,1 ;（ADHCNT＝ADHCNT－１）＝０の時 次の命令をスキップする
GOTO ADHEN_LOOP3 ;ADHEN_LOOP3へ ジャンプする （充電待ちループ）
;---Ａ／Ｄ変換を開始する （ＧＯビットをＯＮ＜１＞にする）
BSF ADCON0,GO ;ADCON0レジスタ（ＧＯビット） ← 1
;---Ａ／Ｄ変換の完了を待つ（ＧＯビットがＯＦＦ＜０＞になるまで）
ADHEN_LOOP31
BTFSC ADCON0,GO ;ADCON0レジスタ（GOﾋﾞｯﾄ）＝０の時 次の命令をスキップする
GOTO ADHEN_LOOP31 ;ADHEN_LOOP31へ ジャンプする （Ａ／Ｄ変換完了待ちループ）
;---Ａ／Ｄ変換結果の取得--- A/D変換出力値(10ﾋﾞｯﾄ) → ADRESHレジスタ(上位8ﾋﾞｯﾄ)
;-----ADHSAV(Ａ／Ｄ変換値上位)：ADRESHレジスタ(A/D変換結果上位) をセットする
MOVF ADRESH,0 ;Ｗレジスタ ← ADRESHレジスタ(A/D変換結果上位)
MOVWF ADHSAV ;ADHSAV(Ａ／Ｄ変換値上位)← Ｗレジスタ
;-----ADLSAV(Ａ／Ｄ変換値下位)：ADRESLレジスタ(A/D変換結果下位) をセットする
BSF STATUS,RP0 ;■バンク１にする （ ステータスレジスタのRP0 ← 1 ）
MOVF ADRESL,0 ;Ｗレジスタ ← ADRESLレジスタ(A/D変換結果下位)
BCF STATUS,RP0 ;■バンク０に戻す （ ステータスレジスタのRP0 ← 0 ）
MOVWF ADLSAV ;ADLSAV(Ａ／Ｄ変換値下位)← Ｗレジスタ
ADHEN_END
RETURN
・
・
・
・
・
●計算値を算出してから測定した値との比較です。
測定電圧 計算値 測定値
（Ｖ） （10進数）（10進数）
・0.0 0 0
・0.5 102 79
・1.0 205 179
・1.5 307 291
・2.0 409 397
・2.5 512 490
・3.0 614 600
・3.5 716 705
・4.0 818 815
・4.5 921 911
・5.0 1023 1023
測定電圧（Ｖ）÷ 基準電圧(電源電圧)（５Ｖ）Ｘ 1023(変換段階数) ＝ A/D変換出力値
●なんとなく、Ａ／Ｄ変換出力値の測定ができた感じですが・・・
この環境下で測定すると、想定した値と違います。こんなものかしら？
こんな小世界の測定は、まるで、ミクロの決死圏みたいだな (^^；
・
・
・
・
・
